【Access VBA】実践演習 #2 (検索機能の実装)

流れとしては以下です
1.「Q_書籍検索」を使ってレコードセットを取得
2. 必要に応じてFilterプロパティに条件式を設定。⇒ レコードセット再取得
3. 手順2. を検索条件毎に行う。
4. 得られたレコードセットをフォームに再設定 ⇒ フォームを更新

では順に実装していきます。
まずDB接続とレコードセットの取得までが以下のコードになります。
[vb] Private Sub 検索ボタン_Click()

‘ 変数の宣言
Dim db As DAO.Database
Dim rs As DAO.Recordset

‘ 現在開いているデータベースに接続
Set db = CurrentDb()

‘「Q_書籍検索」を使ってレコードセットを取得
Set rs = db.OpenRecordset("Q_書籍検索", dbOpenDynaset)

End Sub
[/vb]

ここで取得したレコードセットは全件取得しているので、Filterプロパティを使って絞り込みを行います。
Filterプロパティの使い方は以下。

これを、「タイトル」「カテゴリ」「著者」に値が入力されている時のみ実行するようにしたのが以下のコードです。
[vb] ‘ タイトルが入力されている場合
If IsNull(Me.検索_タイトル) = False Then
rs.Filter = "タイトル like ‘*" & Me.検索_タイトル & "*’"
Set rs = rs.OpenRecordset
End If

‘ カテゴリが入力されている場合
If IsNull(Me.検索_カテゴリ) = False Then
rs.Filter = "カテゴリ名 = ‘" & Me.検索_カテゴリ.Column(1) & "’"
Set rs = rs.OpenRecordset
End If

‘ 著者が入力されている場合
If IsNull(Me.検索_著者) = False Then
rs.Filter = "著者 like ‘*" & Me.検索_著者 & "*’"
Set rs = rs.OpenRecordset
End If
[/vb]

Filterプロパティの設定値は文字列結合が絡んでいるので見づらくなっています。
不安な方は一度固定値で条件式を作成して確認してみてください。
また、Filterを設定した後に「Set rs = rs.OpenRecordset」でレコードセットを再取得しています。
Filterプロパティは設定するたびに以前のフィルターを無効化してしまうので、
これが無いと複数条件を指定した時に、最後の条件しか効かなくなってしまいます。
気になる方はコメントにして動作確認してみてください。

ここまででフィルター処理済みのレコードセットが取得できたので、
最後にフォームのレコードセットを再設定します。
[vb] Set Me.Recordset = rs
Me.Requery
[/vb] 「Me.Requery」は無くても動くかと思いますが、念のためフォームの更新をかけています。

以上をまとめたコードが以下です。
[vb] Private Sub 検索ボタン_Click()

‘ 変数の宣言
Dim db As DAO.Database
Dim rs As DAO.Recordset

‘ 現在開いているデータベースに接続
Set db = CurrentDb()

‘「Q_書籍検索」を使ってレコードセットを取得
Set rs = db.OpenRecordset("Q_書籍検索", dbOpenDynaset)

‘ タイトルが入力されている場合
If IsNull(Me.検索_タイトル) = False Then
rs.Filter = "タイトル like ‘*" & Me.検索_タイトル & "*’"
Set rs = rs.OpenRecordset
End If

‘ カテゴリが入力されている場合
If IsNull(Me.検索_カテゴリ) = False Then
rs.Filter = "カテゴリ名 = ‘" & Me.検索_カテゴリ.Column(1) & "’"
Set rs = rs.OpenRecordset
End If

‘ 著者が入力されている場合
If IsNull(Me.検索_著者) = False Then
rs.Filter = "著者 like ‘*" & Me.検索_著者 & "*’"
Set rs = rs.OpenRecordset
End If

Set Me.Recordset = rs

Me.Requery

End Sub
[/vb]

‘ 全件取得のSQLを作成
sql = "SELECT * FROM 蔵書一覧 LEFT OUTER JOIN カテゴリ一覧 ON 蔵書一覧.CATEGORY_ID = カテゴリ一覧.CATEGORY_ID WHERE 1 = 1"

‘ タイトルが入力されている場合
If IsNull(Me.検索_タイトル) = False Then
sql = sql & " AND タイトル like ‘*" & Me.検索_タイトル & "*’"
End If

‘ カテゴリが入力されている場合
If IsNull(Me.検索_カテゴリ) = False Then
sql = sql & " AND カテゴリ名 = ‘" & Me.検索_カテゴリ.Column(1) & "’"
End If

‘ 著者が入力されている場合
If IsNull(Me.検索_著者) = False Then
sql = sql & " AND 著者 like ‘*" & Me.検索_著者 & "*’"
End If

‘ データベースに接続
Set db = CurrentDb()

‘ SQLでレコードセットを取得
Set rs = db.OpenRecordset(sql, dbOpenDynaset)

Set Me.Recordset = rs

Me.Requery

End Sub
[/vb]

まず初めにベースとなるSQLを作成していきます。
欲しいのは蔵書一覧ですが、カテゴリーはIDではなく名前で取得したいので、カテゴリ一覧テーブルを結合します。
念のため左外部結合を使って以下のようなSQLになります。
[sql] SELECT * FROM 蔵書一覧 LEFT OUTER JOIN カテゴリ一覧
ON 蔵書一覧.CATEGORY_ID = カテゴリ一覧.CATEGORY_ID
[/sql]

これで問題無いのですが、7行目のSQLでは「WHERE 1=1」という検索に影響しない条件式を繋げています。
これはこの後の「タイトル」「カテゴリ」「著者」のフィルター実装をシンプルにするための工夫です。
(WHEREを付ける付けない、ANDを付ける付けないの分岐処理を省略することができます。)

SQLが作成できれば、あとはOpenRecordsetの引数に指定することで、
いきなり目的のレコードセットが取得できます。

‘ 検索条件を空にする
Me.検索_タイトル = Null
Me.検索_カテゴリ = Null
Me.検索_著者 = Null

‘ 「Q_書籍検索」の結果をフォームに設定
Dim db As DAO.Database
Dim rs As DAO.Recordset

Set db = CurrentDb()
Set rs = db.OpenRecordset("Q_書籍検索", dbOpenDynaset)

Set Me.Recordset = rs

Me.Requery

End Sub
[/vb] 検索条件を空にするところは、「Me.検索_タイトル = “”」のようにしても
見かけ上問題無く動作しますが、その状態で「検索」ボタンをクリックすると何も表示されないケースが生まれます。
(IsNULLの判定が空文字に対してはFalseになってしまうため。)

データの取得は練習2-1と同じように行い、フィルターをかけずにフォームにセットするだけなので、
練習2-1の内容を理解していれば簡単かと思います。

‘ 検索条件を空にする
Me.検索_タイトル = Null
Me.検索_カテゴリ = Null
Me.検索_著者 = Null

‘ 「Q_書籍検索」の結果をフォームに設定
Dim db As DAO.Database
Dim rs As DAO.Recordset
Dim sql As String

‘ 全件取得のSQLを作成
sql = "SELECT * FROM 蔵書一覧 LEFT OUTER JOIN カテゴリ一覧 ON 蔵書一覧.CATEGORY_ID = カテゴリ一覧.CATEGORY_ID"

Set db = CurrentDb()
Set rs = db.OpenRecordset(sql, dbOpenDynaset)

Set Me.Recordset = rs

Me.Requery

End Sub
[/vb] 今回のようにクエリが用意されていればあえてSQLを記述する必要は無いので、
基本的には解答例①の方法で良いかと思います。

解答例は以下になります。
[vb] Private Sub 貸出ボタン_Click()

If Me!貸出状況 = "貸出可" Then
DoCmd.OpenForm "F_貸出登録", acNormal, "", "BOOK_ID=" & Me.BOOK_ID
Else
MsgBox "貸出中の書籍です。", vbCritical
End If

End Sub
[/vb]

前回と同じようにDoCmd.OpenFormを使いますが、第4引数でBOOK_IDによるフィルターをかけています。
第2、第3引数は特別な設定は不要なので規定値にしています。
貸出状況による分岐はIf文を使って作成しています。

解答例は以下になります。
[vb] Private Sub 編集ボタン_Click()
DoCmd.Close acForm, "F_書籍編集"
DoCmd.OpenForm "F_書籍編集", OpenArgs:=Me!BOOK_ID
End Sub
[/vb]

ここで渡しているBOOK_IDは編集の処理を作成する時に使用します。

なお、渡した値が受け取れているか確認する場合、
「F_書籍編集」の「Form_Open」イベントに以下の様に記述すると良いです。
[vb] Private Sub Form_Open(Cancel As Integer)
MsgBox OpenArgs
End Sub
[/vb] 渡したときと同じ「OpenArgs」という変数名で受け取ることができます。